Calcoliamo lo spazio per ogni step

Se impostiamo a priori uno spazio che il carrello deve percorrere dopo ogni scatto, succede che lo spazio totale percorso, dipende dal numero di foto che facciamo scattare.
Sarebbe bello fare in modo che il carrello dello slider si muovi di quel tanto, in modo tale che alla fine delle foto scattate, il carrello abbia percorso tutto lo spazio disponibile.
Lo possiamo fare con un pò di matematica:

int MotoreDir=3;
int MotoreStep=4;
int MotoreEnable=5;
int Led=13;
int Scatto=2;

//definiamo le variabili che useremo
int NumeroPassi=200;//Il motore dovrebbe fare un giro 200×1,8°=360°
int Attesa=5000;//1 secondo tra un giro e l’altro
int Velocita=5;//Tempo di attesa tra uno step e l’altro. Più è basso questo valore più è veloce il motore
boolean Direzione = false;//variabile per gestire la direzione del motore
int NumeroFotoDaScattare = 300;//variabile per gestire il numero di foto da scattare
int NumeroFotoScattata = 0;
int AttesaDopoMovimento = 300;//per evitare vibrazioni, possiamo mettere una piccola pausa subito dopo il movimento
int DurataScatto=400;//Variabile per indicare quanto tempo (in millisecondi) deve essere simulata la pressione dello scatto
int AttesaDopoScatto = 300;//per evitare vibrazioni, possiamo mettere una piccola pausa prima di ricominciare a muovere
unsigned long TempoInizioPasso;//variabile per morizzare il tempo di inizio di un nuovo passo


//dati dello slider
unsigned long LgBinarioInMm=920;//!< Lunghezza utile del binario in millimetri (utile perchè dobbiamo togliere lo spazio occupato dal carrello)
float MotorStepSize = 1.8f;//!< l'angolo di step del motore , solitamente 1,8°
float PassoCinghia = 5;//!< Il passo della cinghia, solitamente T5
float DentiPuleggiaMotrice = 16;//!< Il numero di denti della puleggia motrice
float Riduttore = 14; // Se abbiamo interposto un riduttore tra motore e puleggia, inserire qui il valore

//calcoliamo ora il numero di passi necessari per compiere 
float StepNecessari = LgBinarioInMm * Riduttore * (360.0f /  MotorStepSize) / (PassoCinghia * DentiPuleggiaMotrice);
//dividendo questo valore trovato per il numero di foto da scattare si ha il numero di passi da far eseguire per muovere ogni volta il motore.
//poichè il risultato ottenuto potrebbe essere un numero decimale, arrotondiamo direttamente il valore.
//in questo modo evitiamo eventuali differenze di arrotondamento che possono capitare ma soprattutto
//manteniamo costante lo spazio percorso.
//Con questo arrotondamento, può succedere che lo spazio percorso non sia tutto lo spazio utile, ma in teoria si dovrebbero perdere solamente alcuni 
//millimetri.
float NumeroPassiStep= StepNecessari / (float) NumeroFotoDaScattare;



void setup() {
      pinMode(MotoreDir, OUTPUT); // imposto il pin indicato come uscita
      pinMode(MotoreStep, OUTPUT); // imposto il pin indicato come uscita
      pinMode(MotoreEnable, OUTPUT); // imposto il pin indicato come uscita
      pinMode(Scatto, OUTPUT); // imposto il pin indicato come uscita
      pinMode(Led, OUTPUT); // imposto il pin indicato come uscita
      TempoInizioPasso=millis();
      NumeroPassi = NumeroPassiStep;
}

void loop(){
      if (NumeroFotoScattata<NumeroFotoDaScattare)
      {
        if (millis() - TempoInizioPasso > Attesa)
        {
            TempoInizioPasso = millis();
            AccendiLed();
            Motore();
            SpegniLed();
            Scatta();
            NumeroFotoScattata++;//Incrementiamo il numero di foto scattate. 
                                 //Scritta in questo modo, questa riga equivale a 
                                 //NumeroFotoScattata = NumeroFotoScattata + 1
         }
      }        
}

void AccendiLed(void){
      digitalWrite(Led, HIGH);//accendiamo il led
}
void SpegniLed(void){
      digitalWrite(Led, LOW);//spegnamo il led
}

void Motore(void){
      if (Direzione==true) digitalWrite(MotoreDir, HIGH);//Abilitiamo un senso di rotazione
      if (Direzione==false) digitalWrite(MotoreDir, LOW);//Abilitiamo il senso opposto
      digitalWrite(MotoreEnable, LOW);//Abilitiamo la scheda passo passo abbassando il livello logico dell’uscita
      for (int ciclo=0;ciclo<NumeroPassi;ciclo++){
            //diamo un impulso al motore
            digitalWrite(MotoreStep, LOW);
            delayMicroseconds(2);
            digitalWrite(MotoreStep, HIGH);
            delayMicroseconds(2);
            delay(Velocita);//attesa per il prossimo impulso
      }
      digitalWrite(MotoreEnable, HIGH);//Disabilitiamo la scheda passo passo alzando il livello logico dell’uscita
}

void Scatta(void){
  delay(AttesaDopoMovimento);
  digitalWrite(Scatto, HIGH);//Iniziamo a simulare la pressione dello scatto
  delay(DurataScatto);
  digitalWrite(Scatto, LOW);//terminiamo lo scatto
  delay(AttesaDopoScatto);
}

Aggiungiamo uno schermo LCD

Lascia un commento

Il tuo indirizzo email non sarà pubblicato. I campi obbligatori sono contrassegnati *

Donate

Support TLTools, Make A Donation

Please make a donation if you enjoy using our software and believe in the importance of what the ciemmesoft is working to accomplish.

PayPal Donate Button

Fai una donazione!

Sostieni il progetto, fai una donazione TLTools è un progetto gratuito. Fai una donazione se ti piace utilizzare il nostro software e se credi nell'importanza di ciò a cui il progetto lavora.

PayPal Donate Button